[AJUDA] Codigo]

21 Jun 2020, 15:13

ola amigos
esse codigo abaixo faz com que o personagem fique no lado do helicoppetro atirando como se fosse o "H" no carro

porem ele tbm seta M4, como eu poderia manter esse mod so tirando essa setagem de M4, para so manter as armas que o personagem tem?

SpoilerAbrir

// This file was decompiled using SASCM.ini published by GTAG (http://gtag.gtagaming.com/opcode-database) on 14.6.2013
{$CLEO .cs}

//-------------MAIN---------------
thread "MADH_SAMP"

:MADH_SAMP_13
wait 0
if and
Player.Defined($PLAYER_CHAR)
0AB0: key_pressed 17
0AB0: key_pressed 72
jf @MADH_SAMP_13
wait 0
Model.Load(#M4)
if and
Model.Available(#M4)
044B: actor $PLAYER_ACTOR on_foot
jf @MADH_SAMP_78
jump @MADH_SAMP_13

:MADH_SAMP_78
wait 0
$HELI = Actor.CurrentCar($PLAYER_ACTOR)
if or
Car.Id($HELI) == #MAVERICK
Car.Id($HELI) == #POLMAV
jf @MADH_SAMP_78
wait 0
fade 0 500
wait 500
0633: AS_actor $PLAYER_ACTOR exit_car
Actor.GiveWeaponAndAmmo($PLAYER_ACTOR, M4, 60000)
wait 2000
06A7: put_actor $PLAYER_ACTOR into_turret_on_car $HELI at_car_offset 1.25 1.4 0.1 position 1 shooting_angle 100.0 120.0 with_weapon 30
wait 500
fade 1 500

:MADH_SAMP_196
wait 0
if
Actor.Dead($PLAYER_ACTOR)
jf @MADH_SAMP_228
0465: remove_actor $PLAYER_ACTOR from_turret_mode
jump @MADH_SAMP_13

:MADH_SAMP_228
wait 0
if and
0AB0: key_pressed 17
0AB0: key_pressed 71
jf @MADH_SAMP_196
0465: remove_actor $PLAYER_ACTOR from_turret_mode
0430: put_actor $PLAYER_ACTOR into_car $HELI passenger_seat 0
jump @MADH_SAMP_13

21 Jun 2020, 19:27

Esse script tá mal feito.

21 Jun 2020, 20:04

Israel escreveu: ↑
21 Jun 2020, 19:27
Esse script tá mal feito.

como q eu poderia simplificar esse codigo amigo

a função é ficar "pendurado" no heli atirando
como nessa imagem

SpoilerAbrir

23 Jun 2020, 05:45

Esse script tá muito mal feito, você dizer que ele funciona minimamente já é algo incrível.

Refiz:

Código: Selecionar tudo

SCRIPT_START
{
    LVAR_INT scplayer iSeat iSide iVehModel iTotalSeats hChar hVeh iWeaponType iPassenger
    LVAR_FLOAT x y z

    GET_PLAYER_CHAR 0 scplayer

    WHILE TRUE
        WAIT 0
        IF IS_KEY_PRESSED VK_LCONTROL
        AND IS_KEY_PRESSED VK_KEY_H
            IF IS_CHAR_SITTING_IN_ANY_CAR scplayer
                GET_CAR_CHAR_IS_USING scplayer hVeh
                GOSUB GetSeat
                GOSUB GetSideBySeat

                GET_CURRENT_CHAR_WEAPON scplayer iWeaponType
                WARP_CHAR_FROM_CAR_TO_COORD scplayer 0.0 0.0 0.0

                IF DOES_VEHICLE_EXIST hVeh
                AND NOT IS_CHAR_DEAD scplayer
                    ATTACH_CHAR_TO_CAR scplayer hVeh x y z iSide 120.0 iWeaponType

                    GOSUB WaitKey

                    WHILE DOES_VEHICLE_EXIST hVeh
                    AND NOT IS_CHAR_DEAD scplayer
                        WAIT 0
                        IF IS_KEY_PRESSED VK_LCONTROL
                        AND IS_KEY_PRESSED VK_KEY_H
                            DETACH_CHAR_FROM_CAR scplayer
                            IF iSeat = -1
                                WARP_CHAR_INTO_CAR scplayer hVeh
                            ELSE
                                WARP_CHAR_INTO_CAR_AS_PASSENGER scplayer hVeh iSeat
                            ENDIF
                            GOSUB WaitKey
                            BREAK
                        ENDIF
                    ENDWHILE
                ENDIF
            ENDIF
        ENDIF
    ENDWHILE

    WaitKey:
    WHILE IS_KEY_PRESSED VK_LCONTROL
    AND IS_KEY_PRESSED VK_KEY_H
        WAIT 0
    ENDWHILE
    RETURN

    GetSeat:
    iSeat = -1
    GET_DRIVER_OF_CAR hVeh hChar
    IF hChar = scplayer
        RETURN
    ENDIF
    GET_MAXIMUM_NUMBER_OF_PASSENGERS hVeh iTotalSeats
    WHILE iSeat < iTotalSeats
        GET_CHAR_IN_CAR_PASSENGER_SEAT hVeh iSeat hChar
        IF hChar = scplayer
            RETURN
        ENDIF
        iTotalSeats++
    ENDWHILE
    RETURN

    GetSideBySeat:
    GET_CAR_MODEL hVeh iVehModel
    GET_MODEL_DIMENSIONS iVehModel x y z z z z
    ABS_LVAR_FLOAT x
    x += 0.5
    y = 1.4
    z = 0.1
    SWITCH iSeat
        CASE -1 // driver
        CASE 1 // lr
            iSide = FACING_LEFT
            x *= -1.0
            BREAK
        CASE 0 // rf
        CASE 2 // rr
            iSide = FACING_RIGHT
            BREAK
        DEFAULT
            iSide = FACING_FORWARD
            BREAK
    ENDSWITCH
    RETURN
}
SCRIPT_END

Este inclusive funciona em qualquer veículo, em qualquer banco.
https://sharemods.com/c3nehe1lmkjp/Turr ... 1_.7z.html

23 Jun 2020, 21:40

Junior_Djjr escreveu: ↑

23 Jun 2020, 05:45

Esse script tá muito mal feito, você dizer que ele funciona minimamente já é algo incrível.

Refiz:

Código: Selecionar tudo

SCRIPT_START
{
    LVAR_INT scplayer iSeat iSide iVehModel iTotalSeats hChar hVeh iWeaponType iPassenger
    LVAR_FLOAT x y z

    GET_PLAYER_CHAR 0 scplayer

    WHILE TRUE
        WAIT 0
        IF IS_KEY_PRESSED VK_LCONTROL
        AND IS_KEY_PRESSED VK_KEY_H
            IF IS_CHAR_SITTING_IN_ANY_CAR scplayer
                GET_CAR_CHAR_IS_USING scplayer hVeh
                GOSUB GetSeat
                GOSUB GetSideBySeat

                GET_CURRENT_CHAR_WEAPON scplayer iWeaponType
                WARP_CHAR_FROM_CAR_TO_COORD scplayer 0.0 0.0 0.0

                IF DOES_VEHICLE_EXIST hVeh
                AND NOT IS_CHAR_DEAD scplayer
                    ATTACH_CHAR_TO_CAR scplayer hVeh x y z iSide 120.0 iWeaponType

                    GOSUB WaitKey

                    WHILE DOES_VEHICLE_EXIST hVeh
                    AND NOT IS_CHAR_DEAD scplayer
                        WAIT 0
                        IF IS_KEY_PRESSED VK_LCONTROL
                        AND IS_KEY_PRESSED VK_KEY_H
                            DETACH_CHAR_FROM_CAR scplayer
                            IF iSeat = -1
                                WARP_CHAR_INTO_CAR scplayer hVeh
                            ELSE
                                WARP_CHAR_INTO_CAR_AS_PASSENGER scplayer hVeh iSeat
                            ENDIF
                            GOSUB WaitKey
                            BREAK
                        ENDIF
                    ENDWHILE
                ENDIF
            ENDIF
        ENDIF
    ENDWHILE

    WaitKey:
    WHILE IS_KEY_PRESSED VK_LCONTROL
    AND IS_KEY_PRESSED VK_KEY_H
        WAIT 0
    ENDWHILE
    RETURN

    GetSeat:
    iSeat = -1
    GET_DRIVER_OF_CAR hVeh hChar
    IF hChar = scplayer
        RETURN
    ENDIF
    GET_MAXIMUM_NUMBER_OF_PASSENGERS hVeh iTotalSeats
    WHILE iSeat < iTotalSeats
        GET_CHAR_IN_CAR_PASSENGER_SEAT hVeh iSeat hChar
        IF hChar = scplayer
            RETURN
        ENDIF
        iTotalSeats++
    ENDWHILE
    RETURN

    GetSideBySeat:
    GET_CAR_MODEL hVeh iVehModel
    GET_MODEL_DIMENSIONS iVehModel x y z z z z
    ABS_LVAR_FLOAT x
    x += 0.5
    y = 1.4
    z = 0.1
    SWITCH iSeat
        CASE -1 // driver
        CASE 1 // lr
            iSide = FACING_LEFT
            x *= -1.0
            BREAK
        CASE 0 // rf
        CASE 2 // rr
            iSide = FACING_RIGHT
            BREAK
        DEFAULT
            iSide = FACING_FORWARD
            BREAK
    ENDSWITCH
    RETURN
}
SCRIPT_END

Este inclusive funciona em qualquer veículo, em qualquer banco.
https://sharemods.com/c3nehe1lmkjp/Turr ... 1_.7z.html

vc é fera cara vou testar aq
tem algum site onde podemos pegar os nomes para os comandos?

07 Jul 2020, 03:10

Melhorei mais o script e botei .ini

Postei lá: https://www.mixmods.com.br/2020/07/turr ... hicle.html

leneilson27 escreveu: ↑
23 Jun 2020, 21:40
tem algum site onde podemos pegar os nomes para os comandos?

f141-gta3script-cleo/t26-indice-de-tuto ... gta3script

Forum.MixMods

[AJUDA] Codigo]

[AJUDA] Codigo]

Re: [AJUDA] Codigo]

Re: [AJUDA] Codigo]

Re: [AJUDA] Codigo]

Re: [AJUDA] Codigo]

Re: [AJUDA] Codigo]