Como Colocar Uma Marquinha Vermelha Em Um Char

16 Ago 2018, 18:08

Gostaria De Saber Como Posso Criar Essa Marca Em Um Char, Igual O Mod GUN SELLER Faz Quando Você Chama O Vendedor, Ele Fica Aparecendo
No Mapa.

16 Ago 2018, 18:39

Comando:

Código: Selecionar tudo

ADD_BLIP_FOR_CHAR (char) (blip)

Exemplo:

Código: Selecionar tudo

SCRIPT_START
{

    LVAR_INT scplayer char blip
    LVAR_FLOAT x y z

    GET_PLAYER_CHAR 0 (scplayer)

    loop:
    WAIT 0
    IF IS_KEY_PRESSED VK_KEY_1
        GET_OFFSET_FROM_CHAR_IN_WORLD_COORDS (scplayer) (0.0 3.0 0.0) (x y z)
        CREATE_RANDOM_CHAR (x y z) (char)
        ADD_BLIP_FOR_CHAR (char) (blip)
        WHILE IS_KEY_PRESSED VK_KEY_1
            WAIT 0
        ENDWHILE
    ENDIF

    GOTO loop

}
SCRIPT_END

16 Ago 2018, 19:53

Você Poderia Me Explicar O Que é Esse:

Código: Selecionar tudo

GET_OFFSET_FROM_CHAR_IN_WORLD_COORDS

16 Ago 2018, 20:04

no exemplo que ele deu é pegar as coordenadas de 3 metros a frente do char que no caso é o player

16 Ago 2018, 20:12

RyanVinicius escreveu: ↑
16 Ago 2018, 19:53
Você Poderia Me Explicar O Que é Esse:
Código: Selecionar tudo
GET_OFFSET_FROM_CHAR_IN_WORLD_COORDS

Esse comando pega as coords de um char, com um offset especificado por você.

16 Ago 2018, 21:21

voce deve esta fazendo algo assim, mais ou menos o que fiz na missão de saltar de paraquedas.

Código: Selecionar tudo

SCRIPT_START
{
    NOP

    LVAR_INT scplayer char blip in_mission 
    LVAR_FLOAT x, y, z

    GET_PLAYER_CHAR 0 scplayer

    Main_Loop:
        WAIT 0
        IF IS_PLAYER_CONTROL_ON 0 // apenas se o controle 1 estiver habilitado
            READ_MEMORY 0x96ABA0 1 FALSE ( in_mission )
            IF (in_mission = 0) // Apenas se não estiver em missão
                IF NOT DOES_CHAR_EXIST char // se este char não existir
                AND LOCATE_CHAR_ANY_MEANS_3D scplayer 2490.04, -1667.31, 13.34, 25.0, 25.0, 5.0, FALSE // apenas se estiver nestas coordenadas (groove)
                    CLEO_CALL Create_New_Char_In_Coords 0 (2490.04, -1667.31, 13.34) (22) (char) // criar o char
                    ADD_BLIP_FOR_CHAR char blip // adiciona a marca ao char 
                    CHANGE_BLIP_COLOUR blip 1 // escolhe cor da marca
                    CHANGE_BLIP_SCALE blip 1 // escolher tamanho da marca
                    WHILE DOES_CHAR_EXIST char // manter se estiver nestas coordenadas e se char existir.
                    AND LOCATE_CHAR_ANY_MEANS_3D scplayer 2490.04, -1667.31, 13.34, 25.0, 25.0, 5.0, FALSE
                        IF IS_CHAR_DEAD char // sair se o char morrer.
                            BREAK
                        ELSE
                            //-- 
                                // este char trabalhando aqui
                                GET_OFFSET_FROM_CHAR_IN_WORLD_COORDS char 0.0 1.0 0.0 x, y, z // pegar coordenadas na frente deste char 
                                TASK_TURN_CHAR_TO_FACE_CHAR char scplayer // fazer um char olhar para o player
                                IF LOCATE_CHAR_ANY_MEANS_3D scplayer x, y, z, 1.0, 1.0, 1.0, FALSE // criar uma marca na frente do player 
                                    PRINT_STRING_NOW "Ele esta dizendo algo, voce concorda com o que ele diz? Y/N" 10
                                    IF IS_BUTTON_PRESSED 0 11 // Y para Sim 
                                        PRINT_STRING_NOW "Voce concordou" 1500
                                        TASK_PLAY_ANIM scplayer "endchat_01" "ped" 4.0 FALSE FALSE FALSE FALSE -1 // animação se concordar do player
                                        //-- fazer algo aqui 
                                        WAIT 1500
                                    ENDIF
                                    IF IS_BUTTON_PRESSED 0 10 // N para Não 
                                        PRINT_STRING_NOW "Voce nao concordou" 1500
                                        TASK_PLAY_ANIM scplayer "endchat_02" "ped" 4.0 FALSE FALSE FALSE FALSE -1 // animação se não concordar do player
                                        TASK_PLAY_ANIM char "endchat_03" "ped" 4.0 FALSE FALSE FALSE FALSE -1 // animação do char
                                        //-- fazer algo aqui 
                                        WAIT 1500
                                        //-- 
                                        WHILE LOCATE_CHAR_ANY_MEANS_3D scplayer x, y, z, 1.0, 1.0, 1.0, FALSE 
                                            WAIT 4 
                                        ENDWHILE
                                    ENDIF                                    
                                ENDIF
                            //-- 
                        ENDIF
                        WAIT 0
                    ENDWHILE
                    REMOVE_BLIP blip
                    IF DOES_CHAR_EXIST char //-- se o char ainda existir fazer isto 
                        MARK_CHAR_AS_NO_LONGER_NEEDED char // descartar o char
                        WHILE DOES_CHAR_EXIST char // se o char morrer e existir manter até ele ser deletado
                            WAIT 0 
                        ENDWHILE
                    ENDIF
                ENDIF
            ENDIF
        ENDIF
    GOTO Main_Loop
}

{
    LVAR_FLOAT x, y, z, 
    LVAR_INT model, char

    Create_New_Char_In_Coords:
        IF NOT HAS_MODEL_LOADED model 
            REQUEST_MODEL model 
            LOAD_ALL_MODELS_NOW
        ENDIF 
        CREATE_CHAR 4, model, x, y, z, char 
        MARK_MODEL_AS_NO_LONGER_NEEDED model 
    CLEO_RETURN 0 char
}
SCRIPT_END

Forum.MixMods

Como Colocar Uma Marquinha Vermelha Em Um Char [RESOLVIDO]

Como Colocar Uma Marquinha Vermelha Em Um Char

Re: Como Colocar Uma Marquinha Vermelha Em Um Char [RESOLVIDO]

Re: Como Colocar Uma Marquinha Vermelha Em Um Char

Re: Como Colocar Uma Marquinha Vermelha Em Um Char

Re: Como Colocar Uma Marquinha Vermelha Em Um Char

Re: Como Colocar Uma Marquinha Vermelha Em Um Char