[SA/Ideia] Mod CLEO para spawn fixo (drop) de roupas/skin

18 Jan 2022, 22:38

Boa noite, precisava de ajuda de voces para me ajudar em algum mod cleo para Gta Sa onde eu pudesse colocar uma marca no chao (pode ser até aqueles flutuantes de entrar em casas) em um ponto especifico do mapa (coordenada) e a roupa do Cj mudasse pra uma que está no script ou então mudasse para alguma skin do proprio jogo, e quanto pisasse denovo no icone, voltava pro cj original.

eu ja achei um mod identico ao que eu precisava porem está em Lua e era pra MTA, onde não funciona para Single Player. O script é esse para terem ideia:

Código: Selecionar tudo

zombiehunterpickup55555 = createPickup ( 1294.62109375, -1333.2423095703, 21.955364227295, 3, 1275, 1000 )
function zombiehunterskinpickup55555 ( thePlayer )
  setPedSkin ( thePlayer, 274 )
  setPlayerTeam ( thePlayer, teamzombie )
 setElementData ( thePlayer, "zombie", true  )  
end
addEventHandler ( "onPickupUse", zombiehunterpickup55555, zombiehunterskinpickup55555 )
addEventHandler ("onPickupUse", getRootElement(),

function (playerWhoUses)
  if (source == zombiehunterpickup55555) then
    setPlayerNametagText (playerWhoUses, "" .. getPlayerName (playerWhoUses))
    setElementData (playerWhoUses, "job", "farm")
  end
end)

Aqui um link do Youtube de um video de como funcina o codigo acima e meio que explica o que quero fazer:
Pulem pro 2:38 em caso de preguiça.

Caso me perguntem pra que preciso disso, é porque estou "melhorando" um mod de Batman bem antigo e que possui diversos Batsuits e skins dos peds legais que só acessam por Cheat Menu e gostaria de deixar certos pontos fixos nas batcavernas que possui no mapa do mod onde eu apenas passasse por cima e a roupa mudasse. Será de grande ajuda.

Eu já consegui fazer com carros (batmobiles) usando o codigo seguinte:

Código: Selecionar tudo

014B: 1@ = init_car_generator #POLMAV color -1 -1 force_spawn 1 alarm 0 door_lock 0 min_delay 0 max_delay 10000 at 659.6589 -2473.244 38.70618 angle -90.0
014C: set_parked_car_generator 1@ cars_to_generate_to 101

e armas com esse:

Código: Selecionar tudo

032B: 1@ = create_weapon_pickup #SILENCED type 15 ammo 9999 at -760.1733 -1969.976 13.44299

Funciona muito bem, mas na hora de colocar as roupas, ja não sei fazer :/ Agradeço de toda forma!

19 Jan 2022, 12:50

If you create any pickup that is not health, armor or weapon then you need to check if it has been collected.
Here is an example CLEO script that creates a clothes pickup for the Combat Jacket in front of the Santa Maria Beach safehouse:

SpoilerAbrir

Código: Selecionar tudo

{$CLEO .cs}

//get the player's ped's handle
01F5: 0@ = get_player_actor 0

//set pickup as non-existent
1@ = -1

//work in an infinite loop
while true
    //create pickup if non-existent
    if 1@ == -1
    then
        0213: 1@ = create_pickup 1275 type 3 at 324.6231 -1787.2544 4.7892
    end

    //if not health, armor or weapon, then needed to check if pickup has been collected
    if 0214: pickup 1@ picked_up
    then
        //remove pickup and set as non-existent
        0215: destroy_pickup 1@
        1@ = -1

        //fade out
        016A: fade 0 time 250
        wait 500

        //set player clothes
        087B: set_player 0 clothes_texture "FIELD" model "FIELD" body_part 0

        //apply the clothes' changes
        070D: rebuild_player 0

        //put the player somewhat far from the pickup so that it doesn't accidentaly get collected again
        00A1: put_actor 0@ at 324.6231 -1789.2544 3.7892
        0173: set_actor 0@ Z_angle_to 180.0

        //fade in
        wait 500
        016A: fade 1 time 250
    end

    //don't skip any frames
    wait 0
end

21 Jan 2022, 12:24

HzanRsxa2959 escreveu: ↑

19 Jan 2022, 12:50

If you create any pickup that is not health, armor or weapon then you need to check if it has been collected.
Here is an example CLEO script that creates a clothes pickup for the Combat Jacket in front of the Santa Maria Beach safehouse:

SpoilerAbrir

Código: Selecionar tudo

{$CLEO .cs}

//get the player's ped's handle
01F5: 0@ = get_player_actor 0

//set pickup as non-existent
1@ = -1

//work in an infinite loop
while true
    //create pickup if non-existent
    if 1@ == -1
    then
        0213: 1@ = create_pickup 1275 type 3 at 324.6231 -1787.2544 4.7892
    end

    //if not health, armor or weapon, then needed to check if pickup has been collected
    if 0214: pickup 1@ picked_up
    then
        //remove pickup and set as non-existent
        0215: destroy_pickup 1@
        1@ = -1

        //fade out
        016A: fade 0 time 250
        wait 500

        //set player clothes
        087B: set_player 0 clothes_texture "FIELD" model "FIELD" body_part 0

        //apply the clothes' changes
        070D: rebuild_player 0

        //put the player somewhat far from the pickup so that it doesn't accidentaly get collected again
        00A1: put_actor 0@ at 324.6231 -1789.2544 3.7892
        0173: set_actor 0@ Z_angle_to 180.0

        //fade in
        wait 500
        016A: fade 1 time 250
    end

    //don't skip any frames
    wait 0
end

Muito obrigado!! no campo "clothes_texture "FIELD" model "FIELD"" eu posso simplesmente colocar o modelo com o nome do DFF e a textura com o nome do TXD que ja vai funcionar? Como seria se caso a roupa estiver mais partes, como torso, pernas, sapatos, etc?

21 Jan 2022, 20:29

kaiqueknup escreveu: ↑
21 Jan 2022, 12:24
in the field "clothes_texture "FIELD" model "FIELD"" I can simply put the model with the name of the DFF and the texture with the name of the TXD that will work?

Yes: you need to simply put the DFF name for the model and the TXD name for the texture.

kaiqueknup escreveu: ↑
21 Jan 2022, 12:24
How would it be if the clothes were more parts, such as torso, legs, shoes, etc?

The body_part parameter decides where the specified part of clothing will appear. Here is a link to the enumerator: BodyPart (also available in Sanny Builder -> Help -> Offline help... -> SCM Documentation -> Player body parts; may be outdated).
Do this for each part of the cloth for it to be worn completely, like this:

Código: Selecionar tudo

087B: set_player 0 clothes_texture "SUITTORSO" model "SUITTORSO" body_part 0
087B: set_player 0 clothes_texture "SUITLEGS" model "SUITLEGS" body_part 2
087B: set_player 0 clothes_texture "SUITSHOES" model "SUITSHOES" body_part 3

23 Jan 2022, 20:39

HzanRsxa2959 escreveu: ↑
21 Jan 2022, 20:29

kaiqueknup escreveu: ↑
21 Jan 2022, 12:24
in the field "clothes_texture "FIELD" model "FIELD"" I can simply put the model with the name of the DFF and the texture with the name of the TXD that will work?
Yes: you need to simply put the DFF name for the model and the TXD name for the texture.

kaiqueknup escreveu: ↑
21 Jan 2022, 12:24
How would it be if the clothes were more parts, such as torso, legs, shoes, etc?
The body_part parameter decides where the specified part of clothing will appear. Here is a link to the enumerator: BodyPart (also available in Sanny Builder -> Help -> Offline help... -> SCM Documentation -> Player body parts; may be outdated).
Do this for each part of the cloth for it to be worn completely, like this:
Código: Selecionar tudo
087B: set_player 0 clothes_texture "SUITTORSO" model "SUITTORSO" body_part 0
087B: set_player 0 clothes_texture "SUITLEGS" model "SUITLEGS" body_part 2
087B: set_player 0 clothes_texture "SUITSHOES" model "SUITSHOES" body_part 3

Simplesmente incrível! você é demais cara, obrigado mesmo

24 Jan 2022, 02:56

kaiqueknup escreveu: ↑
23 Jan 2022, 20:39
Simplesmente incrível! você é demais cara, obrigado mesmo

Se tiver resolvido o seu problema, marque o tópico como resolvido clicando no botão verde na resposta que te ajudou.

Forum.MixMods

[SA/Ideia] Mod CLEO para spawn fixo (drop) de roupas/skin [PRONTO]

[SA/Ideia] Mod CLEO para spawn fixo (drop) de roupas/skin

Re: [SA/Ideia] Mod CLEO para spawn fixo (drop) de roupas/skin

Re: [SA/Ideia] Mod CLEO para spawn fixo (drop) de roupas/skin [PRONTO]

Re: [SA/Ideia] Mod CLEO para spawn fixo (drop) de roupas/skin

Re: [SA/Ideia] Mod CLEO para spawn fixo (drop) de roupas/skin

Re: [SA/Ideia] Mod CLEO para spawn fixo (drop) de roupas/skin