[SA] GTA V Drunk Cam effect

03 Mai 2018, 00:18

[GTA SA] Drunk Cam effect like GTA V

Hello!

I've been trying to create CLEO Scripts for GTA SA and I've also made some. But need help with my Drunk Cam script. Can anyone pls help?

About:
This cam is activated by a keypress configurable through .ini and when in a vehicle and if it's speed increases the sake value of camera increases.

PS: I'm new to CLEO scripting. So pls forgive me for my mistakes.

The script:

Open up for scriptAbrir

Código: Selecionar tudo

 // This file was decompiled using SASCM.ini published by GTAG (http://gtag.gtagaming.com/opcode-database) on 14.6.2013
{$CLEO .cs}

//-------------MAIN---------------
03A4: name_thread 'DRUNK' 
0001: wait 0 ms 
00D6: if 
8AAB:   not file_exists "CLEO\Drunk Cam.ini" 
004D: jump_if_false @DRUNK_181 
0AF1: write_int 75 to_ini_file "CLEO\Drunk Cam.ini" section "Config" key "DC_Start" 
0AF1: write_int 75 to_ini_file "CLEO\Drunk Cam.ini" section "Config" key "DC_End" 
0AF1: write_int 50 to_ini_file "CLEO\Drunk Cam.ini" section "Config" key "Effect" 
0001: wait 0 ms 
0002: jump @DRUNK_181 

:DRUNK_181
0001: wait 0 ms 
0AF0: 0@ = get_int_from_ini_file "CLEO\Drunk Cam.ini" section "Config" key "DC_Start" 
0AF0: 1@ = get_int_from_ini_file "CLEO\Drunk Cam.ini" section "Config" key "DC_End"  
0AF0: 2@ = get_int_from_ini_file "CLEO\Drunk Cam.ini" section "Config" key "Effect" 
0001: wait 0 ms 
0002: jump @DRUNK_321 

:DRUNK_321
0001: wait 0 ms 
00D6: if 
0256:   player $PLAYER_CHAR defined 
004D: jump_if_false @DRUNK_321 
0001: wait 0 ms 
0002: jump @DRUNK_352 

:DRUNK_352
0001: wait 0 ms 
00D6: if 
0AB0:   key_pressed 0@ 
004D: jump_if_false @DRUNK_391 
052C: set_player $PLAYER_CHAR drunk_visuals 2@ 
0001: wait 100 ms 
0002: jump @DRUNK_391 

:DRUNK_391
0001: wait 0 ms 
00D6: if 
0AB0:   key_pressed 1@ 
004D: jump_if_false @DRUNK_352 
052C: set_player $PLAYER_CHAR drunk_visuals 0 
0001: wait 100 ms 
0002: jump @DRUNK_429 

:DRUNK_429
0001: wait 0 ms 
00D6: if 
00DF:   actor $PLAYER_ACTOR driving 
004D: jump_if_false @DRUNK_352
wait 0
jump  @Drunk_456

:Drunk_456
wait 0 
00D9: 3@ = actor $PLAYER_ACTOR car // add to mission cleanup 
02E3: 4@ = car 3@ speed 
00D6: if 
0019:   4@ > 60 
004D: jump_if_false @DRUNK_429 
0085: 2@ = 5@ // (int)
000A: 5@ += 70 
052C: set_player $PLAYER_CHAR drunk_visuals 5@ 
0001: wait 1000 ms 
0002: jump @DRUNK_352

When on foot it works, but when enter and ride a car, it crashes.

PLS Help!!!!!

03 Mai 2018, 00:45

Did you create this script from the scratch? I mean, you decompiled a script, so I don't think you created it.

03 Mai 2018, 00:51

You're not creating, you're editing someone's code. Mods are not created in this way. Even skilled people have difficulties in making mods in this way.

Unfortunately the two best cleo tutorials I can indicate are in Portuguese, if you use Portuguese-English translation the result is good.
Check this: f141-secao-tutorial-gta3script/t26-indi ... gta3script

Zaz's tutorial also serves but I don't like it much, his tutorial is confusing.

Another thing is that if you are going to learn to do cleo by focusing on one or the other mod, you will not be able to. You will have to learn how to make mods, not to make a mod.

03 Mai 2018, 13:42

Matheus Rivaldo escreveu: ↑ Did you create this script from the scratch? I mean, you decompiled a script, so I don't think you created it.

I made it. I just decompiled my own script to view how it has decompiled.

Added after 1 minute 12 seconds:

Junior_Djjr escreveu: ↑
03 Mai 2018, 00:51

Junior_Djjr escreveu: ↑ You're not creating, you're editing someone's code.

No man, I made it. Wait let me showy own script. Wait.

03 Mai 2018, 13:43

Can you send us your source code?

03 Mai 2018, 13:47

Junior_Djjr, I have a lot of respect for u and I won't lie to u. It's my script.

Added after 1 minute 10 seconds:

Matheus Rivaldo escreveu: ↑ Can you send us your source code?

Yes if course but at morning. Time to sleep, eh.

03 Mai 2018, 23:25

Hello! My source code for my Drunk Cam effect

SpoilerAbrir

{$CLEO .cs}

03A4: name_thread 'Drunk'

:DRUNK_1
wait 0
00D6: if
8AAB: not file_exists "CLEO\Drunk Cam.ini"
004D: jump_if_false @Drunk_Get
0AF1: write_int 75 to_ini_file "cleo\Drunk Cam.ini" section "Config" key "DC_Start"
0AF1: write_int 75 to_ini_file "cleo\Drunk Cam.ini" section "Config" key "DC_End"
0AF1: write_int 50 to_ini_file "cleo\Drunk Cam.ini" section "Config" key "Effect"
wait 0
jump @Drunk_Get

:Drunk_Get
wait 0
0AF0: 0@ = get_int_from_ini_file "cleo\Drunk Cam.ini" section "Config" key "DC_Start"
0AF0: 1@ = get_int_from_ini_file "cleo\Drunk Cam.ini" section "Config" key "DC_End"
0AF0: 2@ = get_int_from_ini_file "cleo\Drunk Cam.ini" section "Config" key "Effect"
wait 0
jump @Drunk_Main

:Drunk_Main
wait 0
if
0256: player $PLAYER_CHAR defined
004D: jump_if_false @Drunk_Main
wait 0
jump @Drunk_2

:Drunk_2
wait 0
00D6: if
0AB0: key_pressed 0@
004D: jump_if_false @Drunk_3
052C: set_player $PLAYER_CHAR drunk_visuals 2@
wait 100
jump @Drunk_3

:Drunk_3
wait 0
00D6: if
0AB0: key_pressed 1@
004D: jump_if_false @Drunk_2
052C: set_player $PLAYER_CHAR drunk_visuals 0
wait 100
jump @Drunk_Car

:Drunk_Car
wait 0
00D6: if
00DF: actor $PLAYER_ACTOR driving
004D: jump_if_false @Drunk_Car
00D9: 3@ = actor $PLAYER_ACTOR car
wait 0
jump @Drunk_C2

:Drunk_C2
02E3: 4@ = car 3@ speed
00D6: if
0019: 4@ > 60
004D: jump_if_false @Drunk_Car
000A: 2@ += 70
052C: set_player $PLAYER_CHAR drunk_visuals 2@
wait 1000
jump @Drunk_2

This is my GTAinside.com userpage www.gtainside.com/user/Techno-Sachin

04 Mai 2018, 02:20

And it's low level, such irony.
Again: Mods are not created in this way. Even skilled people have difficulties in making mods in this way.

Well, you don't need to "wait 0" before jump (why? Do you know what is "wait 0"?), and you don't need to jump to the line bellow, the script is read from up to down, it automatically reads the following line.
Car speed isn't INT, it's FLOAT.
When you increase 2@, well, you increased... The value will be e.g. 70, 140, 210, 280... ...inf
00D9: is only for mission.

Look:

Código: Selecionar tudo

{$cleo}
0000:

const
iniDC_Start = 0@
iniDC_End = 1@
iniEffect = 2@  
iniEffectIncreased = 6@ 
car = 3@
speed = 4@
drunkEnabled = 5@
end

if 8AAB:   not file_exists "CLEO\Drunk Cam.ini"
then   
    0AF1: write_int 75 to_ini_file "cleo\Drunk Cam.ini" section "Config" key "DC_Start"
    0AF1: write_int 75 to_ini_file "cleo\Drunk Cam.ini" section "Config" key "DC_End"
    0AF1: write_int 50 to_ini_file "cleo\Drunk Cam.ini" section "Config" key "Effect"
end

0AF0: iniDC_Start = get_int_from_ini_file "cleo\Drunk Cam.ini" section "Config" key "DC_Start"
0AF0: iniDC_End = get_int_from_ini_file "cleo\Drunk Cam.ini" section "Config" key "DC_End"
0AF0: iniEffect = get_int_from_ini_file "cleo\Drunk Cam.ini" section "Config" key "Effect"

while true
    wait 0
    if drunkEnabled == false
    then           
        // Check enable
        if 0AB0:   key_pressed iniDC_Start
        then                        
            drunkEnabled = true  
            052C: set_player 0 drunk_visuals iniEffect
            while 0AB0:   key_pressed iniDC_Start
                wait 0
            end
        end    
    else
        // Check disable
        if 0AB0:   key_pressed iniDC_End
        then           
            drunkEnabled = false
            052C: set_player 0 drunk_visuals 0
            while 0AB0:   key_pressed iniDC_End
                wait 0
            end
        end
        // Apply increased drunk when driving
        if 00DF:   actor $player_actor driving
        then
            03C0: car = actor $player_actor car
            02E3: speed = car car speed
            if speed > 30.0
            then
                0A8E: iniEffectIncreased = iniEffect + 70
                052C: set_player 0 drunk_visuals iniEffect
            end
        end    
    end
end

05 Mai 2018, 00:03

Thank you Junior_Djjr. I love u for helping me. I'm a newcomer to this scripting. Thank u for correcting my script.

PS: Can I post this here in this forum???

Added after 5 minutes 16 seconds:
Actually where to exactly use 'wait 0' ?? Can u please tell me??

05 Mai 2018, 02:46

TS_999 escreveu: ↑
05 Mai 2018, 00:03
Thank you Junior_Djjr. I love u for helping me. I'm a newcomer to this scripting. Thank u for correcting my script.

PS: Can I post this here in this forum???

Added after 5 minutes 16 seconds:
Actually where to exactly use 'wait 0' ?? Can u please tell me??

Can you translate and use my tutorial? Really, almost everything you ask me is explained there, I would just keep repeating.

05 Mai 2018, 09:10

wait 0 is used in loops, for example:

Código: Selecionar tudo

{$CLEO}
0000:

while true
    wait 0
    if player.Defined(0)
    then
        if 0AB0:   key_pressed 75
        then
            05BE: AS_actor $PLAYER_ACTOR die
            while 0AB0:   key_pressed 75
                wait 0
            end
        end
    end
end

I don't know if the code above works because my GTA isn't working, so I can't test it.

05 Mai 2018, 13:18

Matheus Rivaldo escreveu: ↑ wait 0 is used in loops, for example:
Código: Selecionar tudo
{$CLEO}
0000:

while true
    wait 0
    if player.Defined(0)
    then
        if 0AB0:   key_pressed 75
        then
            05BE: AS_actor $PLAYER_ACTOR die
            while 0AB0:   key_pressed 0x73
                wait 0
            end
        end
    end
end
I don't know if the code above works because my GTA isn't working, so I can't test it.

Thanks man for the help

Added after 2 minutes 19 seconds:

Junior_Djjr escreveu: ↑
TS_999 escreveu: ↑
05 Mai 2018, 00:03
Thank you Junior_Djjr. I love u for helping me. I'm a newcomer to this scripting. Thank u for correcting my script.

PS: Can I post this here in this forum???

Added after 5 minutes 16 seconds:
Actually where to exactly use 'wait 0' ?? Can u please tell me??
Can you translate and use my tutorial? Really, almost everything you ask me is explained there, I would just keep repeating.

Hey, man thanks a lot. I also made the script to be reloadable in game.

Tomorrow, I will be releasing it here and GTAinside.com Ok.

05 Mai 2018, 13:21

I forgot to change the VKey in the second loop of my script. Fixed

05 Mai 2018, 17:58

Matheus Rivaldo escreveu: ↑wait 0 is used in loops

Agora ele via pensar que é só isso.

05 Mai 2018, 17:59

Eu ia dizer que é usado em loops na MAIORIA das vezes, mas fiquei em dúvida.

Forum.MixMods