Change Car Color - Mudar as 4 cores dos carros

16 Ago 2019, 15:21

Já faz muito tempo que eu fiz este mod, não cheguei a postar antes porque já há vários mods do tipo, mas caso haja alguém que assim como eu, prefere algo mais simples:

Imagem

Digite "Color" para abrir o menu.
Caso você cancele a seleção de cores, o carro voltará para a cor que já estava.

SourceAbrir

Código: Selecionar tudo

{$Cleo}
0ADF: add_dynamic_GXT_entry "CC_TTL" text "Change Color"
0ADF: add_dynamic_GXT_entry "CC_HDR" text "Indices"

0ADF: add_dynamic_GXT_entry "CC_PRI" text "Primary Color"
0ADF: add_dynamic_GXT_entry "CC_SEC" text "Secondary Color"
0ADF: add_dynamic_GXT_entry "CC_TER" text "Tertiary Color"
0ADF: add_dynamic_GXT_entry "CC_QUA" text "Quaternary Color"

while true
    wait 0
    
    if and
        0ADC:   test_cheat "Color"
        Actor.Driving($Player_Actor)
    jf continue
    
    0@ = Actor.CurrentCar($Player_Actor)            
    Player.CanMove(0, false)
    
    repeat
        08D4: 1@ = create_panel_with_title 'CC_TTL' position 29.0 145.0 width 186.0 columns 1 interactive 1 background 1 alignment 1
        08DB: set_panel 1@ column 0 header 'CC_HDR' data 'CC_PRI' 'CC_SEC' 'CC_TER' 'CC_QUA' "dummy" "dummy" "dummy" "dummy" "dummy" "dummy" "dummy" "dummy"
        0512: show_permanent_text_box 'WARDH3' // menu help text

        repeat
            wait 0
            
            if 00E1:   player 0 pressed_key 15 // enter_vehicle
            then
                2@ = true
                break
            end
        until 00E1:   player 0 pressed_key 16 // sprint
        
        0AB1: call_scm_func @Holding 2 false true
        
        if 2@ == true
        then
            2@ = false
            break
        end
        
        08D7: 3@ = panel 1@ active_row
        0A97: 20@ = car 0@ struct
        005A: 20@ += 3@
        20@ += 0x434 // m_nPrimaryColor
        
        08DA: remove_panel 1@
        0964: create_square_color_panel 'dummy' position 29.0 145.0 width 25.7 columns 8 interactive 1 background 1 alignment 1 panelID 1@
        0512: show_permanent_text_box 'MODH6' // color menu help text
        
        03F3: get_car 0@ primary_color_to 5@ secondary_color_to 6@
        0A12: get_car 0@ tertiary_color_to 7@ quaternary_color_to 8@

        repeat
            wait 0
            
            if 00E1:   player 0 pressed_key 15 // enter_vehicle
            then
                0229: set_car 0@ primary_color_to 5@ secondary_color_to 6@
                0A11: set_car 0@ tertiary_color_to 7@ quaternary_color_to 8@

                break
            end
                                
            08D7: 4@ = panel 1@ active_row

            0AA7: call_function 0x005822B0 num_params 2 pop 2 row 4@ panel 1@ -> 10@ // GetCarColourFromGrid
            0A8C: write_memory 20@ size 1 value 10@ vp 0
        until 00E1:   player 0 pressed_key 16 // sprint
        
        08DA: remove_panel 1@
        0AB1: call_scm_func @Holding 2 true true
    until 00E1:   player 0 pressed_key 15    
    
    0AB1: call_scm_func @Holding 2 true false    
        
    Player.CanMove(0, true)
    08DA: remove_panel 1@
    03E6: remove_text_box    
end

:Holding
if 0@ == true
then
    while 00E1:   player 0 pressed_key 15 // enter_vehicle
        wait 0
    end
end

if 1@ == true
then
    while 00E1:   player 0 pressed_key 16 // sprint
        wait 0
    end
end

0AB2: ret 0

DOWNLOAD

16 Ago 2019, 17:40

como tu moveu o radar?

16 Ago 2019, 17:51

Kaneki-ken escreveu: ↑
16 Ago 2019, 17:40
como tu moveu o radar?

Um mod que eu fiz para uso pessoal que muda completamente o hud.

17 Ago 2019, 01:04

Israel escreveu: ↑
16 Ago 2019, 17:51

Kaneki-ken escreveu: ↑
16 Ago 2019, 17:40
como tu moveu o radar?
Um mod que eu fiz para uso pessoal que muda completamente o hud.

kk qer conpartilhar n?

17 Ago 2019, 01:54

puedes agregar soporte para escojer tambien paintjobs incluyendo el 5to paintjob?

17 Ago 2019, 09:28

Kaneki-ken escreveu: ↑
17 Ago 2019, 01:04
kk qer conpartilhar n?

Não.

Kr0n0s800 escreveu: ↑
17 Ago 2019, 01:54
puedes agregar soporte para escojer tambien paintjobs incluyendo el 5to paintjob?

Não.

17 Ago 2019, 17:36

A terceira e quarta cor estão mudando a cor da segunda aqui

17 Ago 2019, 20:15

Mystertv escreveu: ↑
17 Ago 2019, 17:36
A terceira e quarta cor estão mudando a cor da segunda aqui

É normal do jogo isso. Acontece se o veículo não possuir terceira e/ou quarta. Não é bem assim, veja.

17 Ago 2019, 21:02

Eu testei na Camper e esse Elegy que tem 4 cores também.

Esse aqui funciona perfeitamente as 4, mas esse seu tem um jeito de uso mais interessante
https://www.mixmods.com.br/2015/11/quic ... es-do.html

Camper tem 3 e esse Elegy 4
Imagem

17 Ago 2019, 21:32

Mystertv escreveu: ↑
17 Ago 2019, 21:02
Eu testei na Camper e esse Elegy que tem 4 cores também.

O opcode que eu usei não funciona da maneira que eu esperava, funciona somente para as cores primárias e secundárias:

Imagem

Fiz de forma diferente, chamando a função diretamente. Agora funciona bem.
Atualizei o download e o source no tópico.

Forum.MixMods

Change Car Color - Mudar as 4 cores dos carros

Change Car Color - Mudar as 4 cores dos carros

Re: Change Car Color - Mudar cores dos carros

Re: Change Car Color - Mudar cores dos carros

Re: Change Car Color - Mudar cores dos carros

Re: Change Car Color - Mudar cores dos carros

Re: Change Car Color - Mudar cores dos carros

Re: Change Car Color - Mudar cores dos carros

Re: Change Car Color - Mudar cores dos carros

Re: Change Car Color - Mudar cores dos carros

Re: Change Car Color - Mudar cores dos carros