Página 1 de 2

[SA] Procurar coisas nos sacos de lixo

Enviado: 11 Jun 2018, 22:12
por HybridTheory
Este mod adiciona a possibilidade de procurar coisas nos sacos de lixo, pressionando F quando estiver perto deles. Você pode encontrar coisas úteis, ou engraçadas. (armas, comida, cerveja, dildos, ...e um mendigo.)

Imagem
Imagem
Imagem


SourceAbrir

Código: Selecionar tudo

SCRIPT_START

{
    LVAR_INT scplayer hObject hTaskSequence
    LVAR_FLOAT x y z

    GET_PLAYER_CHAR 0 (scplayer)

    WHILE TRUE
        WAIT 0
        GET_CHAR_COORDINATES scplayer (x y z)
        IF GET_RANDOM_OBJECT_IN_SPHERE_NO_SAVE_RECURSIVE x y z 2.0 FALSE (hObject)
            IF DOES_OBJECT_HAVE_THIS_MODEL hObject 1264
            OR DOES_OBJECT_HAVE_THIS_MODEL hObject 1265
                GOSUB activate
            ENDIF
        ENDIF
    ENDWHILE

    activate:
    GET_OBJECT_COORDINATES hObject (x y z)
    
    WHILE LOCATE_CHAR_ANY_MEANS_3D scplayer x y z 2.0 2.0 2.0 FALSE
        WAIT 0
        IF IS_BUTTON_PRESSED PAD1 15
            REQUEST_ANIMATION BOMBER
            LOAD_ALL_MODELS_NOW

            OPEN_SEQUENCE_TASK (hTaskSequence)
            TASK_TURN_CHAR_TO_FACE_COORD -1 (x y z)
            TASK_PLAY_ANIM -1 BOM_Plant BOMBER 4.0 0 0 0 0 -1
            CLOSE_SEQUENCE_TASK (hTaskSequence)
            PERFORM_SEQUENCE_TASK scplayer (hTaskSequence)
            CLEAR_SEQUENCE_TASK (hTaskSequence)

            WAIT 2500

            CLEO_CALL RandomThing 0 (scplayer) (scplayer)
        ENDIF
    ENDWHILE

    RETURN

}

SCRIPT_END

{
    LVAR_INT player
    LVAR_INT iWeaponModel hRandom hObject hChar
    LVAR_FLOAT x y z

    RandomThing:
    GENERATE_RANDOM_INT_IN_RANGE 0 10 (hRandom) 

    SWITCH (hRandom)
        CASE 0
            REQUEST_MODEL 2880
            REQUEST_ANIMATION FOOD
            LOAD_ALL_MODELS_NOW
            CREATE_OBJECT_NO_OFFSET 2880 0.0 0.0 0.0 hObject
            MARK_MODEL_AS_NO_LONGER_NEEDED 2880
            TASK_PICK_UP_OBJECT player hObject 0.0 0.0 0.0 6 16 "NULL" "NULL" 0
            TASK_PLAY_ANIM player EAT_Burger FOOD 4.0 0 0 0 0 -1
            WAIT 5000
            DELETE_OBJECT hObject
            REMOVE_ANIMATION FOOD
            BREAK
        CASE 1
            REQUEST_MODEL 325
            LOAD_ALL_MODELS_NOW
            GIVE_WEAPON_TO_CHAR player WEAPONTYPE_FLOWERS 1
            BREAK
        CASE 2
            REQUEST_MODEL 321
            LOAD_ALL_MODELS_NOW
            GIVE_WEAPON_TO_CHAR player WEAPONTYPE_DILDO1 1
            TASK_SAY player 11
            BREAK
        CASE 3
            REQUEST_MODEL COLT45
            LOAD_ALL_MODELS_NOW
            GIVE_WEAPON_TO_CHAR player WEAPONTYPE_PISTOL 9
            MARK_MODEL_AS_NO_LONGER_NEEDED COLT45
            BREAK
        CASE 4
            REQUEST_MODEL 2601
            REQUEST_ANIMATION VENDING
            LOAD_ALL_MODELS_NOW
            CREATE_OBJECT_NO_OFFSET 2601 0.0 0.0 0.0 hObject
            MARK_MODEL_AS_NO_LONGER_NEEDED 2601
            TASK_PICK_UP_OBJECT player hObject 0.0 0.0 0.0 5 16 "NULL" "NULL" 0
            TASK_PLAY_ANIM player VEND_Drink_P VENDING 4.0 0 0 0 0 -1
            WAIT 1500
            DELETE_OBJECT hObject
            BREAK 
        CASE 5
            REQUEST_MODEL 1484
            REQUEST_ANIMATION GANGS
            LOAD_ALL_MODELS_NOW
            CREATE_OBJECT_NO_OFFSET 1484 0.0 0.0 0.0 hObject
            MARK_MODEL_AS_NO_LONGER_NEEDED 1484
            TASK_PICK_UP_OBJECT player hObject 0.0 0.0 0.0 6 16 "NULL" "NULL" 0
            TASK_PLAY_ANIM player drnkbr_prtl GANGS 4.0 1 0 0 0 5000
            WAIT 5000
            DELETE_OBJECT hObject
            REMOVE_ANIMATION GANGS
            BREAK
        CASE 6
            ADD_SCORE 0 25
            TASK_SAY player 172
            BREAK
        CASE 7
            REQUEST_MODEL MOLOTOV
            LOAD_ALL_MODELS_NOW
            GIVE_WEAPON_TO_CHAR player WEAPONTYPE_MOLOTOV 1
            BREAK
        CASE 8
            REQUEST_MODEL SPRAYCAN
            LOAD_ALL_MODELS_NOW
            GIVE_WEAPON_TO_CHAR player WEAPONTYPE_SPRAYCAN 200
            BREAK
        CASE 9
            REQUEST_MODEL SBMOTR2
            LOAD_ALL_MODELS_NOW
            GET_OFFSET_FROM_CHAR_IN_WORLD_COORDS player 0.0 1.0 0.0 (x y z)
            CREATE_CHAR PEDTYPE_CIVMALE SBMOTR2 x y z (hChar)
            TASK_FALL_AND_GET_UP hChar 1 0
            TASK_SAY player 108
            MARK_MODEL_AS_NO_LONGER_NEEDED SBMOTR2
            MARK_CHAR_AS_NO_LONGER_NEEDED (hChar) 
            BREAK
    ENDSWITCH
    

    CLEO_RETURN 0 (player)
}

DOWNLOAD
Procurar coisas nos sacos de lixo.7z
(729 Bytes) Baixado 189 vezes

[SA] Procurar coisas nos sacos de lixo

Enviado: 11 Jun 2018, 22:21
por ViniZ0Z
Imagem

[SA] Procurar coisas nos sacos de lixo

Enviado: 11 Jun 2018, 22:35
por Snowflakes
Poderia expandir adicionando estes modelos:

3035
3005
3006
2968
2971
... e alguns outros

[SA] Procurar coisas nos sacos de lixo

Enviado: 11 Jun 2018, 23:20
por Pierre
criativo :att:

edit: tu esqueceu de falar, se tem que apertar algum botão ou etc

[SA] Procurar coisas nos sacos de lixo

Enviado: 11 Jun 2018, 23:31
por Saudoso
Então é ai que vão parar os mendigos...

[SA] Procurar coisas nos sacos de lixo

Enviado: 11 Jun 2018, 23:39
por nadalao
muito legal!

[SA] Procurar coisas nos sacos de lixo

Enviado: 11 Jun 2018, 23:45
por HybridTheory
Pierre escreveu:
11 Jun 2018, 23:20
edit: tu esqueceu de falar, se tem que apertar algum botão ou etc
É. Sou burro :feel:

Adicionei o comando no post.

[SA] Procurar coisas nos sacos de lixo

Enviado: 12 Jun 2018, 01:24
por Ow_Matth
MANO, EU TAVA PENSANDO NISSO ONTEM! Te amo, boludo abrasileirado rs <3


 
edit: como faz aquela coisinha do download ali?  :philo:

[SA] Procurar coisas nos sacos de lixo

Enviado: 12 Jun 2018, 10:13
por HybridTheory
Ow_Matth escreveu:
12 Jun 2018, 01:24
edit: como faz aquela coisinha do download ali?  :philo:

Imagem

[SA] Procurar coisas nos sacos de lixo

Enviado: 12 Jun 2018, 11:01
por Ow_Matth
HybridTheory escreveu:
Ow_Matth escreveu:
12 Jun 2018, 01:24
 
Imagem 
Nuss... Valeu :v 

(+) Eu fui testar o mod agora e não funcionou... Tentei em todo tipo de lixo, inclusive o das prints :T 

[SA] Procurar coisas nos sacos de lixo

Enviado: 12 Jun 2018, 11:23
por Gouter | AlexReal
....  👎

[SA] Procurar coisas nos sacos de lixo

Enviado: 12 Jun 2018, 11:49
por HybridTheory
Ow_Matth escreveu:
12 Jun 2018, 11:01
Eu fui testar o mod agora e não funcionou... Tentei em todo tipo de lixo, inclusive o das prints :T 
Como assim? aqui tá funcionando normal :pokerface:

[SA] Procurar coisas nos sacos de lixo

Enviado: 12 Jun 2018, 12:59
por Um_Geek
Em alguns lugares não é seguro beber bebidas em latinhas do lixo  :toj:

[SA] Procurar coisas nos sacos de lixo

Enviado: 12 Jun 2018, 15:43
por Ow_Matth
HybridTheory escreveu: Como assim? aqui tá funcionando normal
Não acontece nada, nenhuma ação ;-;

[SA] Procurar coisas nos sacos de lixo

Enviado: 12 Jun 2018, 19:22
por Um_Geek
Ow_Matth escreveu:
12 Jun 2018, 15:43
HybridTheory escreveu: Como assim? aqui tá funcionando normal
Não acontece nada, nenhuma ação ;-;  

acho que o taskTurnCharToFaceCoord esta atrapalhando na outra task, talvez seria melhor esperar ele virar para esta posição e depois fazer o taskPlayAnim, mas só suposições mesmo.


.