Gang Spawner (Spawnar membros de gangue e escolher a arma)

02 Mai 2018, 23:21

Um mod simples que eu fiz quando comecei a aprender cleo.

Pressione K + P para ativar o mod;
Use as setas ← & → para escolher um membro de gangue;
Confirme com ENTER;
Use as setas ← & → para escolher uma arma;
Confirme com ENTER;

Escolhendo membro de gangue:
Imagem

Escolhendo arma:
Imagem

DOWNLOAD

SourceAbrir

Código: Selecionar tudo

{$Cleo}
0000:

while true
    wait 0
    
    if and
        0AB0:   key_pressed 0x4B // K
        0AB0:   key_pressed 0x50 // P
    jf continue
    
    Player.CanMove(0, false)    
    04C4: store_coords_to 0@ 1@ 2@ from_actor $Player_Actor with_offset 0.0 3.0 0.0
    
    for 3@ = 102 to 127
        3@ <> 119
        jf continue
        Model.Load(3@)
    end
    
    038B: load_requested_models
    5@ = 102
    
    repeat
        if 4@ <> 0
        then
            Camera.Restore()
            Actor.DestroyInstantly(4@)
        end
        
        4@ = Actor.Create(CivMale, 5@, 0@, 1@, -100.0)
        Actor.LockInCurrentPosition(4@, true)
        0605: actor 4@ perform_animation "FightIdle" IFP "Ped" framedelta 4.0 loop 1 lockX 0 lockY 0 lockF 0 time -1
        067C: put_camera_on_actor 4@ offset 0.0 7.0 1.3 rotation 0.0 -80.0 5.0 tilt 0.0 switchstyle 2
    
        repeat
            wait 0
            
            if 0AB0:   key_pressed 0x25 // VK_LEFT
            then
                if 5@ <= 102
                then 5@ = 127
                else
                    if 5@ == 120
                    then 5@ = 118 
                    else 5@--
                    end
                end
                                
                break  
            end
        
            if 0AB0:   key_pressed 0x27 // VK_RIGHT
            then
                if 5@ >= 127
                then 5@ = 102
                else
                    if 5@ == 118
                    then 5@ = 120 
                    else 5@++
                    end
                end                
                
                break    
            end
            
            0ACD: show_text_highpriority "Escolha um membro de Gangue. ~b~Enter~s~ para confirmar." time 250            
        until 0AB0:   key_pressed 0x0D // VK_RETURN
                
        0AB1: call_scm_func @Holding 2 0x25 0x27
    until 0AB0:   key_pressed 0x0D // VK_RETURN
    
    0AB1: call_scm_func @Holding 1 0x0D
    
    067C: put_camera_on_actor 4@ offset 4.0 0.0 0.5 rotation -180.0 0.0 0.5 tilt 0.0 switchstyle 2
    
    for 3@ = 321 to 326
        Model.Load(3@)
    end
    
    for 3@ = 331 to 372
        if and
            3@ <> 332
            3@ <> 340
            3@ <> 345
            3@ <> 354
        jf continue
        Model.Load(3@)
    end
    
    038B: load_requested_models
    
    repeat
        wait 0
        
        if 0AB0:   key_pressed 0x25 // VK_LEFT
        then
            if 6@ <= 0
            then 6@ = 46
            else
                6@--
                
                if 6@ == 21
                then 6@ = 18
                end
            end
                            
            048F: actor 4@ remove_weapons
            Actor.GiveWeaponAndAmmo(4@, 6@, 99999)  
        end
        
        if 0AB0:   key_pressed 0x27 // VK_RIGHT
        then
            if 6@ >= 46
            then 6@ = 0
            else
                6@++
                
                if 6@ == 19
                then 6@ = 22
                end
            end                
            
            048F: actor 4@ remove_weapons
            Actor.GiveWeaponAndAmmo(4@, 6@, 99999)   
        end
        
        0ACD: show_text_highpriority "Escolha a arma. ~b~Enter~s~ para confirmar." time 250
        0AB1: call_scm_func @Holding 2 0x25 0x27
    until 0AB0:   key_pressed 0x0D // VK_RETURN

    0A96: 7@ = actor 4@ struct
    7@ += 0x598    
    0A8C: write_memory 7@ size 4 value 8 vp 0

    Camera.Restore()
    Actor.LockInCurrentPosition(4@, false)
    Actor.RemoveReferences(4@)
    0631: put_actor 4@ in_group $Player_Group
    
    for 3@ = 102 to 127
        3@ <> 119
        jf continue
        Model.Destroy(3@)
    end
    
    for 3@ = 321 to 326
        Model.Destroy(3@)
    end
    
    for 3@ = 331 to 372
        if and
            3@ <> 332
            3@ <> 340
            3@ <> 345
            3@ <> 354
        jf continue
        Model.Destroy(3@)
    end
    
    Player.CanMove(0, true)    
    4@ = 0
end

:Holding
for 31@ = 0 to 30
    while 0AB0:   key_pressed 0@(31@,1i)
        wait 0
    end
end

0AB2: ret 0

03 Mai 2018, 12:57

Muito bom, poderia fazer uma versão com mais peds!!

03 Mai 2018, 16:31

Muito legal, também acho que seria legal com mais peds mas aí perderia a noção

porque o mod é pra gangs e já tem toas as gangs do jogo.

03 Mai 2018, 16:40

Mike escreveu: ↑
03 Mai 2018, 16:31
mas aí perderia a noção porque o mod é pra gangs e já tem toas as gangs do jogo.

Mais ou menos isso.