[english]
Como usar entradas GXT para mostra textos
Vários comandos, principalmente os antes da CLEO, pedem uma entrada GXT em vez de um texto cru (por exemplo,
ao criar um menu).
O que exatamente é isso?
GXT (GTA Text) é a forma que a Rockstar North usou para a identificação de textos do jogo.
Originalmente os textos são colocados nos tais arquivos .gxt, um para cada tradução, da pasta "text" do jogo.
Felizmente, com a Biblioteca CLEO, nós podemos adicionar entradas GXT
sem editar os arquivos .gxt:
Eu não tenho certeza se as informações aqui valem também para GTA III e GTA VC, testem e confirmem.
Comando ADD_TEXT_LABEL
Como usar:
ADD_TEXT_LABEL EXAMPLE "Example text."
Irá adicionar a entrada GXT
EXAMPLE com o texto
Example text..
Lembre-se de usar até 7 caracteres no nome da entrada GXT (escolha um nome único), e até 127 caracteres no texto. Não deixe espaço no final do texto.
Quando usar:
A vantagem aqui é que você pode personalizar livremente a string do texto, por exemplo enviando um ponteiro para uma string (foi ensinado nas partes sobre manipulação de memória). No entanto, se você for usar um ponteiro, lembre-se que cada entrada GXT precisa de um ponteiro diferente.
A desvantagem é que o texto ficará dentro do seu código, portanto não é simples para alguém traduzir o seu mod para outros idiomas.
Outra desvantagem é que não é legal para a memória RAM comparado ao uso dos arquivos .fxt ensinado abaixo. Você não precisa se preocupar com isso caso seja poucos textos.
Arquivos FXT
Como usar:
Crie um arquivo .fxt dentro da pasta
CLEO/CLEO_TEXT ou em alguma pasta qualquer dentro do ModLoader.
Arquivos .fxt (Fake GTA Text) são arquivos de texto renomeados, portanto basta você criar um
.txt e renomeá-lo / salvá-lo em
.fxt (prefira deixar "Extensões de nomes dos arquivos" ativado no Windows).
No conteúdo do arquivo .fxt, digite por exemplo:
EXAMPLE Example text.
Irá adicionar a entrada GXT
EXAMPLE com o texto
Example text..
Você pode adicionar uma entrada em cada linha:
Código: Selecionar tudo
EXAMPL1 Example 1
EXAMPL2 Example 2
EXAMPL3 Example 3
A vantagem aqui é que qualquer pessoa que saiba mexer no Bloco de notas vai conseguir traduzir o seu mod para outros idiomas.
Outra vantagem é que esta forma é otimizada para o uso de RAM do seu PC.
A desvantagem é que será um pouco mais complicado manipular os textos por script, mesmo assim, tudo é possível e às vezes com este modo é ainda mais fácil. Será ensinado abaixo.
Como adicionar números e textos dentro do seu texto
Utilizando formatação de string
Você primeiro precisa ler o tutorial sobre manipulação de memória, pelo menos a parte 1 e 2.
Criar um texto personalizado com valores e colocar numa entrada GXT (
ADD_TEXT_LABEL), se resume em usar um ponteiro para um buffer (
GET_LABEL_POINTER) e utilizar formatação de string (
STRING_FORMAT), por exemplo:
Código: Selecionar tudo
SCRIPT_START
{
NOP
LVAR_FLOAT x y z
LVAR_INT pString
WHILE TRUE
WAIT 0
GET_ACTIVE_CAMERA_COORDINATES x y z
GET_LABEL_POINTER Buffer (pString)
STRING_FORMAT pString "Coords: X %.3f Y %.3f Z %.3f" x y z
ADD_TEXT_LABEL EXAMPLE $pString
SET_TEXT_CENTRE TRUE
DISPLAY_TEXT 320.0 224.0 EXAMPLE
USE_TEXT_COMMANDS 0
ENDWHILE
}
SCRIPT_END
Buffer:
DUMP
00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 //32 bytes
ENDDUMP
Parece assustador, mas é simples e muito poderoso.
Infelizmente você vai precisar de um ponteiro diferente para cada entrada GXT, por exemplo, você precisará de um segundo
Buffer: no seu script caso você esteja usando duas entradas GXT ao mesmo tempo, caso contrário as duas terão o mesmo texto; o mesmo valor.
Lembrando que é recomendado você ler os tutoriais sobre manipulação de memória antes de tentar entender isto.
%.3f é para adicionar um valor float com precisão de 3 casas decimais. Você pode usar vários outros, inclusive
%s para adicionar uma string dentro de outra, ou
%i para números inteiros etc. É a mesma lógica do
PRINT_FORMATTED /
PRINT_FORMATTED_NOW.
Você encontra a lista de tudo aqui:
http://www.cplusplus.com/reference/cstdio/printf/
Utilizando o sistema original do jogo
Mas de fato você não precisa enfiar as mãos na lama para conseguir algo do tipo. O próprio jogo tem vários comandos que adicionam valores dentro de um texto de uma entrada GXT. Não vou listá-los todos aqui, você encontra procurando por
NUMBER e
STRING.
Por exemplo se você quer que mostre um texto junto com um número, você pode usar
PRINT_WITH_NUMBER_NOW, onde há
~1~ no texto, substituirá pelo número que você enviar:
Arquivo .fxt (mas você também pode usar
ADD_TEXT_LABEL)
E aqui o script:
Código: Selecionar tudo
SCRIPT_START
{
NOP
LVAR_INT cash
WHILE TRUE
WAIT 0
STORE_SCORE 0 cash
SET_TEXT_CENTRE TRUE
DISPLAY_TEXT_WITH_NUMBER 320.0 224.0 EXAMPLE cash
USE_TEXT_COMMANDS 0
ENDWHILE
}
SCRIPT_END
Muito simples, né?
Dica: Caso você só queira mostrar um número sem nenhum texto adicional,
você não precisa adicionar uma entrada GXT para isso, simplesmente use a entrada GXT chamada
NUMBER, ela é uma entrada GXT já existente do jogo que é simplesmente um
~1~.
No caso de colocar uma string dentro de outra, existe o comando
PRINT_STRING_IN_STRING e
PRINT_STRING_IN_STRING_NOW, e neste caso, em vez de
~1~ você usa
~a~.
Agora se você quer fazer operações mais avançadas com caracteres, várias strings e números, é recomendado usar o método anterior, que é mais avançado e potente.
Considerações finais:
Repetindo pela terceira vez:
Lembre-se de usar até 7 caracteres no nome da entrada GXT (escolha um nome único), e até 127 caracteres no texto. Não deixe espaço no final do texto.
É importante que você lembre disso, principalmente o "escolha um nome único".
Muita gente ainda usa nomes comuns.
Se você usar um nome que o jogo ou outro mod já usou, seu mod sobrescreverá o outro texto, ou o contrário.
Por exemplo, se você criar uma entrada GXT com nome
RED irá substituir o texto
Red County do jogo! (e foi isso que aconteceu em versões antigas do In-game Timecyc Editor) Você precisa inventar algo mais único.
Eu recomendo colocar alguma sigla de 3 letras do nome do seu mod, e em seguida algumas letras ou números para dar 7 caracteres.
Por exemplo, no meu mod MDPMv5 eu utilizo entradas chamadas por exemplo
MDPMF1, onde
MDPM é o nome do mod,
F é alguma coisa para eu lembrar (não funcionou, pois agora lembro mais), e em seguida sobra 2 caracteres para eu colocar um número entre 1 e 99, ou 2 letras.
Eu recomendo que você faça algo assim em seus mods também, deste modo o seu mod não causará conflito com outros.
