Pesquisa resultou em 1 ocorrência

por HybridTheory
23 Jul 2018, 18:31
Fórum: Scripts & Códigos
Tópico: [SA] Ganhar estrela de procurado ao fazer burnout
Respostas: 2
Exibições: 334
Gênero:

[SA] Ganhar estrela de procurado ao fazer burnout

Se você fritar os pneus do carro e um policial te ver, você vai ganhar 1 estrela de procurado.

Imagem

Isso também vai chamar a atenção dos pedestres civis, que irão oficar olhando para o carro. O mod não se ativa em missões, e o radius para o policial te ver é configurável no arquivo .ini.


Source codeAbrir

Código: Selecionar tudo

SCRIPT_START
{

    LVAR_INT scplayer car struct gas brake char pedtype pedstruct p i onMission
    LVAR_FLOAT fgas fbrake x y z radius

    IF IS_AUSTRALIAN_GAME 
        CREATE_RANDOM_CHAR 0.0 0.0 0.0 (char)
    ENDIF

    IF NOT READ_FLOAT_FROM_INI_FILE "cleo\Ganhar estrela de procurado ao fazer burnout" "confg" "radius" (radius)
        radius = 20.0
    ENDIF



    GET_PLAYER_CHAR 0 (scplayer)

    WHILE TRUE
        WAIT 0

        READ_MEMORY 0x96ABA0 1 FALSE onMission

        IF onMission = FALSE

            IF IS_CHAR_SITTING_IN_ANY_CAR scplayer
                STORE_CAR_CHAR_IS_IN_NO_SAVE scplayer (car)

                GET_VEHICLE_POINTER car (struct)
                gas = struct + 0x49C
                brake = struct + 0x4A0

                READ_MEMORY brake 4 0 (fbrake)
                READ_MEMORY gas 4 0 (fgas)

                IF fgas > 0.0
                AND fbrake > 0.0
                    WHILE fgas > 0.0
                    AND fbrake > 0.0
                        WAIT 0

                        READ_MEMORY brake 4 0 (fbrake)
                        READ_MEMORY gas 4 0 (fgas)
                        
                        GET_CAR_COORDINATES car (x y z)

                        READ_MEMORY 0x00B74490 4 0 (p)
                        p += 0x04
                        READ_MEMORY p 4 0 (p)
                        i = 0
                        WHILE i <= 0x8B00
                            READ_MEMORY p 1 0 (char)
                            p++
                            IF char >= 0x00
                            AND char < 0x80
                                char += i
                                IF LOCATE_CHAR_ANY_MEANS_3D char x y z radius radius radius FALSE
                                    GOSUB activate
                                ENDIF
                            ENDIF
                            i += 0x100
                        ENDWHILE

                    ENDWHILE 
                ENDIF
            ENDIF
        ENDIF
    ENDWHILE

    activate:
    IF DOES_CHAR_EXIST char
        GET_PED_POINTER char (pedstruct)
        pedstruct += 0x484 
        READ_MEMORY pedstruct 1 FALSE (pedstruct)
        IF pedstruct = 1
            GET_PED_TYPE char (pedtype)
            IF pedtype = 6
                IF NOT IS_WANTED_LEVEL_GREATER 0 1
                    ALTER_WANTED_LEVEL_NO_DROP 0 1
                ENDIF
            ELSE
                TASK_LOOK_AT_CHAR char (scplayer) 5000
            ENDIF
        ENDIF
    ENDIF

    RETURN
    
}
SCRIPT_END


Voltar para “[SA] Ganhar estrela de procurado ao fazer burnout”