[VC] Medical Kit 1.1

06 Dez 2020, 19:14

Adaptação simplificada do Medical Kit RE ao GTA VC, esse mod adiciona um kit médico que pode ser carregado como arma (por padrão substitui a chave de fenda) e pode ser encontrado em frente a hospitais ou nas lojas de ferramentas. Com ele em mãos, pressione TAB ou L1 para curar uma porcentagem de vida do seu personagem instântaneamente.

Funções:

Modelo lowpoly baseado no GTA V, e subsitui também o modelo dos pickups de vida ;
Você pode trocar qual arma o kit substitui ;
Compatível com gamepads ;
É possível escolher a porcentagem de vida a ser curada e caso a vida do personagem esteja acima dessa porcentagem não será possível usar o kit ;
A cura é instântanea e não possui animação ;
Os pickups aparecem em frente aos hospitais e podem ser comprados nas lojas de ferramentas (caso substituia alguma ferramenta de lá) ;
Adicionado um cheat: digite MEDIKAID para ganhar um kit ;

(v1.1)

[VC] Medical kit 1.1.7z: (42.74 KiB) Baixado 122 vezes

[VC] Medical kit 1.1.7z: (42.74 KiB) Baixado 122 vezes

Necessário VC Opcodes
(baixe o VC Opcodes e coloque na pasta CLEO/CLEO_PLUGINS)

Sources:

Medical KitAbrir

Código: Selecionar tudo

SCRIPT_START
{
    LVAR_INT scplayer iWeapId iWeapModel iCurHealth iMinHeal i iHealthToHeal
    LVAR_FLOAT fMinHeal
    
    GET_PLAYER_CHAR 0 scplayer
    READ_INT_FROM_INI_FILE "cleo\Medical Kit.ini" "Weapon Settings" "WeaponId" iWeapId
    READ_INT_FROM_INI_FILE "cleo\Medical Kit.ini" "Weapon Settings" "WeaponModel" iWeapModel
    READ_FLOAT_FROM_INI_FILE "cleo\Medical Kit.ini" "Healing Mechanic" "LifeToHeal" fMinHeal
    WHILE TRUE
        WAIT 0
        IF TEST_CHEAT MEDIKAID
            REQUEST_MODEL iWeapModel
            WHILE NOT HAS_MODEL_LOADED iWeapModel
                WAIT 0
            ENDWHILE
            GIVE_WEAPON_TO_CHAR scplayer iWeapId 1
        ENDIF
        //Main Mechanic
        IF IS_PLAYER_ON_FOOT 0
        AND IS_CURRENT_PLAYER_WEAPON 0 iWeapId
            PRINT_HELP AIDK_1
            WHILE IS_CURRENT_PLAYER_WEAPON 0 iWeapId
                WAIT 0
                IF IS_BUTTON_PRESSED PAD1 LEFTSHOULDER1
                    
                    CLEO_CALL GetHealthPercent 0 (fMinHeal) (iCurHealth, iHealthToHeal)
                    IF iCurHealth < iHealthToHeal
                        SET_PLAYER_HEALTH 0 iHealthToHeal 
                        IF GET_AMMO_IN_PLAYER_WEAPON 0 iWeapId i
                            IF i < 1
                                REMOVE_WEAPON_FROM_CHAR scplayer iWeapId
                            ENDIF
                        ELSE
                            REMOVE_WEAPON_FROM_CHAR scplayer iWeapId
                        ENDIF
                    ELSE
                        CLEAR_HELP
                        PRINT_NOW AIDK_2 2500 1
                    ENDIF
                    
                ENDIF
            ENDWHILE
        ENDIF
    ENDWHILE
}
SCRIPT_END
{
    LVAR_FLOAT fMinHeal //In
    LVAR_INT iCurHealth iMaxHealth iHealthToHeal iCurHealthPercent
    LVAR_FLOAT fCurHealth fMaxHealth fCurHealthPercent fHealthToHeal
    GetHealthPercent:
    GET_PLAYER_HEALTH 0 iCurHealth
    iMaxHealth = 0x94AD28 + 0x143
    READ_MEMORY iMaxHealth 1 FALSE (iMaxHealth)
    fMaxHealth =# iMaxHealth
    fCurHealth =# iCurHealth
    fCurHealthPercent = fCurHealth / fMaxHealth
    fCurHealthPercent *= 100.0
    iCurHealthPercent =# fCurHealthPercent
    fHealthToHeal = fMinHeal / fMaxHealth
    fHealthToHeal *= 100.0
    iHealthToHeal =# fHealthToHeal
    CLEO_RETURN 0 (iCurHealthPercent, iHealthToHeal)
}

24 Dez 2020, 12:54

Atualizado (v1.1):

Corrigido um erro no código que fazia não curar a porcentagem correta

25 Dez 2020, 10:35

Poderia ter um no hotel aonde ele fica, na Vercetti Estate e... Acho que só.

Forum.MixMods

[VC] Medical Kit 1.1

[VC] Medical Kit 1.1

Re: [VC] Medical Kit

Re: [VC] Medical Kit