[VC] Simple Regeneration

04 Dez 2020, 20:28

O mesmo que o Simple Regeneration, porém adaptado ao GTA VC e sem a função de piscar a vida pois não achei uma boa forma de implementar

Script Original: Junior_Djjr
Adaptação ao GTA VC: Neon

[VC] Simple Regeneration.7z: (761 Bytes) Baixado 123 vezes

[VC] Simple Regeneration.7z: (761 Bytes) Baixado 123 vezes

Código: Selecionar tudo

//Original script by Junior_Djjr
//VC adaptation by Neon
SCRIPT_START
{
    LVAR_INT scplayer iPlayerId
    LVAR_INT iCurHealth iLastCurHealth iMaxHealth iWithDelay iFinalHealth
    LVAR_FLOAT fMaxHealth fCurHealth fCurHealthPercent fFinalHealth fIfLessThan fIncreaseTo fUsingSpeed fRegeHealthPercent

    GET_PLAYER_CHAR 0 scplayer

    READ_FLOAT_FROM_INI_FILE "CLEO/Simple Regeneration.ini" "Settings" "IfLessThan" (fIfLessThan)
    READ_FLOAT_FROM_INI_FILE "CLEO/Simple Regeneration.ini" "Settings" "IncreaseTo" (fIncreaseTo)
    READ_FLOAT_FROM_INI_FILE "CLEO/Simple Regeneration.ini" "Settings" "UsingSpeed" (fUsingSpeed)
    READ_INT_FROM_INI_FILE "CLEO/Simple Regeneration.ini" "Settings" "WithDelay" (iWithDelay)

    fIfLessThan /= 100.0
    fIncreaseTo /= 100.0
    fUsingSpeed /= 50.0

    WHILE IS_PC_VERSION
        WAIT 0

        GOSUB StoreValues

        IF fCurHealthPercent < fIfLessThan
            GOSUB RunRegeneration
        ENDIF

    ENDWHILE

    RunRegeneration:
    iLastCurHealth = iCurHealth
    timera = 0
    WHILE timera < iWithDelay
        WAIT 0
        GET_PLAYER_HEALTH 0 (iCurHealth)
        IF NOT iLastCurHealth = iCurHealth
            RETURN
        ENDIF
    ENDWHILE

    fRegeHealthPercent = fCurHealthPercent
    WHILE IS_PC_VERSION
        WAIT 0
        GET_PLAYER_HEALTH 0 (iCurHealth)
        IF iCurHealth < iLastCurHealth // was damaged
            RETURN
        ENDIF
        IF GOSUB StoreValues
        ELSE
            RETURN
        ENDIF
        fRegeHealthPercent [email protected] fUsingSpeed
        IF fRegeHealthPercent > fIncreaseTo
            fRegeHealthPercent = fIncreaseTo
            GOSUB SetHealthByPercent
            BREAK
        ENDIF
        GOSUB SetHealthByPercent
        iLastCurHealth = iFinalHealth
    ENDWHILE

    RETURN

    SetHealthByPercent:
    fFinalHealth = fMaxHealth * fRegeHealthPercent
    iFinalHealth =# fFinalHealth
    SET_PLAYER_HEALTH 0 iFinalHealth
    RETURN

    StoreValues:
    GET_PLAYER_HEALTH 0 (iCurHealth)
    IF iCurHealth > 0
        iMaxHealth = 0x94AD28 + 0x143
        READ_MEMORY iMaxHealth 1 TRUE (iMaxHealth)
        fMaxHealth =# iMaxHealth
        fCurHealth =# iCurHealth
        fCurHealthPercent = fCurHealth / fMaxHealth
        RETURN
    ENDIF
    RETURN
}

SCRIPT_END