Português: f34-tutoriais/t6556-gta-como-corrigir-p ... col-do-ske
If you have already modeled something for the GTA map using Sketchup, and probably other CAD modeling software, you have noticed that the collision model (collider) creates several invisible faces, as if they were invisible, semi-random walls. Unfortunately, they are invisible even through
Draw Cols SA.
They are affected only by people and vehicles, neither the camera nor the shadow is affected, so it is very annoying and difficult to find and understand them.
This is caused because Sketchup fills the T vertices with a triangle in the middle, and this is usually only noticeable after exporting the model.
See below, in the first image we see a T Vertice, it doesn't look like important, but if you pull the vertex, you will notice that there is a triangle there in the middle. Sketchup does this to fill the T Vertice (instead of cutting the edge).
This is the cause of the bug in your collision model. Thanks to the jujubão for the explanation.
It is completely unfeasible to fix each one manually, so I looked for an automated solution: select and delete all faces with a low area value, that is, small, thin.
In the image below, I selected them all in a region and raised them to see them. Too many!
To automatically select all of these faces, and then delete them, I used the script
SelectArea in 3DS Max.
If the link gets lost, here the script, save it in .mcr:
Código: Selecionar tudo
macroScript SelectArea category:"Piranha-Bytes" buttonText:"SelectArea" toolTip:"Select Faces by Area"
(
rollout ro_SelectArea "pb Select Area"
(
pickbutton ui_SA_Obj "Pick Object" pos:[5,5] width:100 height:20 tooltip:"Pick Object"
spinner ui_SA_Area "Area: " pos:[5,30] range:[0,100,0.1] fieldWidth:40 scale:0.1 type:#float
checkButton ui_SA_AreaType "A" pos:[89,30] width:16 height:16 tooltip:"A = Average Area Size, B = Biggest Area Size"
checkButton ui_SA_Less "<" pos:[5,55] width:20 height:20 checked:true tooltip:"Select faces with SMALLER area"
checkButton ui_SA_Equal "=" pos:[25,55] width:20 height:20 checked:false tooltip:"Select faces with EQUAL area"
checkButton ui_SA_More ">" pos:[45,55] width:20 height:20 checked:false tooltip:"Select faces with GREATER area"
button ui_SA_Verts "Verts" pos:[70,55] width:35 height:20 tooltip:"Convert Faceselection to Vertexselection"
local theObj = undefined
local avgArea = 0
local biggestArea = 0
function updateAreaSelection =
(
if theObj != undefined do
(
if ((getCurrentSelection())[1] != theObj) then select theObj
if (subObjectLevel != 4) then subobjectLevel = 4
if ui_SA_AreaType.state == false then theArea = avgArea * (ui_SA_Area.value / 100.0)
if ui_SA_AreaType.state == true then theArea = biggestArea * (ui_SA_Area.value / 100.0)
selMode = 0
if ui_SA_Less.state == true then selMode = 1
if ui_SA_Equal.state == true then selMode = 2
if ui_SA_More.state == true then selMode = 3
faceCount = theObj.faces.count
newFaces = #()
for f = 1 to faceCount do
(
a = (polyOp.getFaceArea theObj f)
if ((selMode == 1) and (a < theArea)) then append newFaces f
if ((selMode == 2) and (a == theArea)) then append newFaces f
if ((selMode == 3) and (a > theArea)) then append newFaces f
)
polyOp.setFaceSelection theObj newFaces
forceCompleteRedraw()
)
)
function init_Obj =
(
faceCount = theObj.faces.count
aa = 0
areaList = #()
for f = 1 to faceCount do
(
a = (polyOp.getFaceArea theObj f)
append areaList a
aa = aa + a
)
avgArea = aa / (faceCount as float)
biggestArea = amax areaList
ui_SA_Area.value = 0.1
select theObj
subObjectLevel = 4
updateAreaSelection()
)
on ro_SelectArea open do
(
curObj = (getCurrentSelection())[1]
if curObj != undefined do
(
objBase = (classof curObj.baseobject) as string
if (objBase == "Editable_Poly") do
(
theObj = curObj
ui_SA_Obj.caption = theObj.name
init_Obj()
)
)
)
on ui_SA_AreaType changed state do
(
if state == true then ui_SA_AreaType.caption = "B"
if state == false then ui_SA_AreaType.caption = "A"
updateAreaSelection()
)
on ui_SA_Obj picked obj do
(
objBase = (classof obj.baseobject) as string
if (objBase == "Editable_Poly") then
(
theObj = Obj
ui_SA_Obj.caption = theObj.name
init_Obj()
)
else messageBox "No Editable Poly !!!"
)
on ui_SA_Area changed val do updateAreaSelection()
on ui_SA_Less changed state do
(
ui_SA_Less.state = true
ui_SA_Equal.state = false
ui_SA_More.state = false
updateAreaSelection()
)
on ui_SA_Equal changed state do
(
ui_SA_Less.state = false
ui_SA_Equal.state = true
ui_SA_More.state = false
updateAreaSelection()
)
on ui_SA_More changed state do
(
ui_SA_Less.state = false
ui_SA_Equal.state = false
ui_SA_More.state = true
updateAreaSelection()
)
on ui_SA_Verts pressed do
(
if theObj != undefined do
(
theObj.convertSelection #Face #Vertex
subObjectLEvel = 1
)
)
)
createDialog ro_SelectArea width:110 style:#(#style_sysmenu, #style_Toolwindow)
)
, including a script I edited to set all materials as white diffuse (fixes dark and saturated model in the LOD transition) and fixes some materials opening with opacity 0.
Other modeling software may have similar solutions available.
I recommend that you place the file in the
Scripts folder of 3DS Max, go to
Customize > Customize User Interface > Keyboard, in the
Category look for
Piranha-Bytes (script creator), select
SelectArea and in
Hotkey put some shortcut, like
Alt+Shift+A.
So, on the selected mesh, add the Modifier
Editable Poly (or convert from the
Editable Mesh with the right button), open and select
Polygon, then press the hotkey.
Enter a low value, I recommend
0.2, but
0.1 can be enough, just use
0.3 for extreme cases on non-detailed models. Hit Enter and see the selected faces (you can quickly see them by moving them upwards), it is important that you have not selected any other important small faces. Once everything is right, delete them with Delete.
Tip: In this script window, click on the object's name and then on another one in the scene explorer, after clicking, it will apply to the other one, so you do it quickly on all objects in the scene, just keep the move tool selected, if the pivot to move appears, then there are faces selected to delete.
I also noticed that exporting col via
GTA Tools > Collision > Export to CST from
Kam's Max Script from Gold Fish generates much less of this bug.
Important: this has to be done with all triangulated faces, a simple way to triangulate is, also in
Editable Poly, go to
Vertex, select all with
Ctrl + A and go to
Connect to connect all, then make the selection.
Also important: It is essential to optimize the collision model before using it, in addition to an important improvement in the game's performance, this avoids invisible faces a lot.
Read the "Optimize COL" section of the tutorial advanced how to create map mod.
If you still see an invisible face, check again, carefully following the steps (including, it may be that a new face appeared while you were touching the model), and if really everything is right, there will be no other way than to correct it manually. I modeled a small town there were dozens, if not more than 100 of these bugs, and after the fix, there was only one left! It was on a straight wall, it didn't have that face there, so I just selected the faces in Coll Editor and clicked on
Replace by Box. To identify the exact source of the bug, you can delete pieces of the model in Coll Editor until the bug disappears, so you can find exactly where it comes from, and try to solve it in some way, be it by remodeling that place, deleting it or replacing it with a box.
I recommend:
How to use Sketchup for GTA / game development
