Converter coordenada 3D para 2D (tela) (útil para debug)

31 Ago 2019, 06:15

Descrição:
A partir de uma coordenada 3D (X Y Z), você pode ter as coordenadas e tamanho (com simulação de profundidade) 2D para desenhar coisas no espaço da tela.

Isto é muito útil para realizar debugging, importante para mods complexos que trabalham com muitas entidades ao mesmo tempo.
Imagem

Eu utilizei isto para criar o novo Real Traffic Fix:

A Rockstar também usou isto durante a criação do jogo:
Imagem

Mas é claro, você também pode simplesmente mostrar informações de gameplay, algo muito usado no SAMP, MTA e jogos modernos, por exemplo "Pressione F para pegar a caixa" sendo mostrado em cima de uma caixa.
Você pode usar isto não só para textos, mas mesmo imagens (sprites)...

Exemplo de uso

gta3script:

Função:

Código: Selecionar tudo

{
    LVAR_FLOAT x y z // In
    LVAR_FLOAT fScreenPosX fScreenPosY
    LVAR_FLOAT fHeight fWidth
    LVAR_FLOAT fBoundingBoxMaxZ
    LVAR_INT i pfOriginPos pfScreenPos pfHeight pfWidth

    Convert3DToScreen2D:
    GET_VAR_POINTER fHeight (pfHeight)
    GET_VAR_POINTER fWidth (pfWidth)
    GET_VAR_POINTER x (pfOriginPos)
    GET_VAR_POINTER fScreenPosX (pfScreenPos)
    //char __cdecl CSprite::CalcScreenCoors(RwV3d *in, RwV3d *out, float *w, float *h, char checkMaxVisible, char checkMinVisible)
    CALL_FUNCTION_RETURN 0x70CE30 6 6 (TRUE TRUE pfHeight pfWidth pfScreenPos pfOriginPos)(i)
    IF NOT i = FALSE
    AND fHeight > 10.0 // only draw if the returned size is not too small: not too far away

        // Convert/Tweak font size
        fWidth /= 100.0
        fHeight /= 50.0

        // Convert screen values to GTA ones
        CLEO_CALL GetXYSizeInScreenScaleByUserResolution 0 (fWidth fHeight)(fWidth fHeight)
        CLEO_CALL GetXYSizeInScreenScaleByUserResolution 0 (fScreenPosX fScreenPosY)(fScreenPosX fScreenPosY)

        RETURN_TRUE
        CLEO_RETURN 0 (fScreenPosX fScreenPosY fWidth fHeight)
    ENDIF
    RETURN_FALSE
    CLEO_RETURN 0 (0.0 0.0 0.0 0.0)
}

{
    LVAR_FLOAT fX fY //In
    LVAR_INT iResX iResY
    LVAR_FLOAT fResX fResY
    GetXYSizeInScreenScaleByUserResolution:
    READ_MEMORY 0xC17044 4 FALSE (iResX)
    READ_MEMORY 0xC17048 4 FALSE (iResY)
    fResX =# iResX
    fResY =# iResY
    fResX /= 640.0
    fX /= fResX
    fResY /= 448.0
    fY /= fResY
    CLEO_RETURN 0 fX fY
}

Chamada:

Código: Selecionar tudo

IF CLEO_CALL Convert3DToScreen2D 0 (fOriginX fOriginY fOriginZ)(fScreenPosX fScreenPosY fSizeX fSizeY)

Exemplo completo:

Código: Selecionar tudo

SCRIPT_START
{
    LVAR_INT hVeh i
    LVAR_FLOAT f fCamX fCamY fCamZ fOriginX fOriginY fOriginZ fScreenPosX fScreenPosY fFontX fFontY fZOffset
    LVAR_TEXT_LABEL t

    NOP

    WHILE TRUE
        WAIT 0
        GET_ACTIVE_CAMERA_COORDINATES (fCamX fCamY fCamZ)
        IF GET_RANDOM_CAR_IN_SPHERE_NO_SAVE_RECURSIVE fCamX fCamY fCamZ 1000.0 FALSE FALSE (hVeh)
            GOSUB DrawVehDebugInfos
            WHILE GET_RANDOM_CAR_IN_SPHERE_NO_SAVE_RECURSIVE fCamX fCamY fCamZ 1000.0 TRUE FALSE (hVeh)
                GOSUB DrawVehDebugInfos
            ENDWHILE
        ENDIF
    ENDWHILE


    DrawVehDebugInfos:
    IF IS_CAR_ON_SCREEN hVeh
        USE_TEXT_COMMANDS 1
        fZOffset = 0.5
        GOSUB DrawVehSpeed
        fZOffset += 0.5
        GOSUB DrawVehName
        USE_TEXT_COMMANDS 0
    ENDIF
    RETURN


    DrawVehName:
    CLEO_CALL GetCoordAboveVehTopWithOffset 0 (hVeh fZOffset)(fOriginX fOriginY fOriginZ)
    IF CLEO_CALL Convert3DToScreen2D 0 (fOriginX fOriginY fOriginZ)(fScreenPosX fScreenPosY fFontX fFontY)

        GOSUB DebugTextFormat

        // Draw text
        GET_CAR_MODEL hVeh (i)
        GET_NAME_OF_VEHICLE_MODEL i (t)
        DISPLAY_TEXT fScreenPosX fScreenPosY $t
    ENDIF
    RETURN


    DrawVehSpeed:
    CLEO_CALL GetCoordAboveVehTopWithOffset 0 (hVeh fZOffset)(fOriginX fOriginY fOriginZ)
    IF CLEO_CALL Convert3DToScreen2D 0 (fOriginX fOriginY fOriginZ)(fScreenPosX fScreenPosY fFontX fFontY)

        GOSUB DebugTextFormat

        // Draw text
        GET_CAR_SPEED hVeh f
        i =# f
        DISPLAY_TEXT_WITH_NUMBER fScreenPosX fScreenPosY NUMBER i
    ENDIF
    RETURN


    DebugTextFormat:
    // Tweak font size
    fFontX *= 2.0
    fFontY *= 2.0
    // Text format
    SET_TEXT_FONT 1
    SET_TEXT_SCALE fFontX fFontY
    SET_TEXT_COLOUR 255 255 255 255
    SET_TEXT_EDGE 1 0 0 0 255
    RETURN
}
SCRIPT_END

{
    LVAR_INT hVeh //In
    LVAR_FLOAT fZOffset //In
    LVAR_FLOAT x y z f fBoundingBoxMaxZ
    LVAR_INT iModel

    GetCoordAboveVehTopWithOffset:
    GET_CAR_MODEL hVeh (iModel)
    GET_MODEL_DIMENSIONS iModel (f f f)(f f fBoundingBoxMaxZ)
    fBoundingBoxMaxZ += fZOffset
    GET_OFFSET_FROM_CAR_IN_WORLD_COORDS hVeh 0.0 0.0 fBoundingBoxMaxZ (x y z)
    CLEO_RETURN 0 (x y z)
}

{
    LVAR_FLOAT x y z // In
    LVAR_FLOAT fScreenPosX fScreenPosY
    LVAR_FLOAT fHeight fWidth
    LVAR_FLOAT fBoundingBoxMaxZ
    LVAR_INT i pfOriginPos pfScreenPos pfHeight pfWidth

    Convert3DToScreen2D:
    GET_VAR_POINTER fHeight (pfHeight)
    GET_VAR_POINTER fWidth (pfWidth)
    GET_VAR_POINTER x (pfOriginPos)
    GET_VAR_POINTER fScreenPosX (pfScreenPos)
    //char __cdecl CSprite::CalcScreenCoors(RwV3d *in, RwV3d *out, float *w, float *h, char checkMaxVisible, char checkMinVisible)
    CALL_FUNCTION_RETURN 0x70CE30 6 6 (TRUE TRUE pfHeight pfWidth pfScreenPos pfOriginPos)(i)
    IF NOT i = FALSE
    AND fHeight > 10.0 // only draw if the returned size is not too small: not too far away

        // Convert/Tweak font size
        fWidth /= 100.0
        fHeight /= 50.0

        // Convert screen values to GTA ones
        CLEO_CALL GetXYSizeInScreenScaleByUserResolution 0 (fWidth fHeight)(fWidth fHeight)
        CLEO_CALL GetXYSizeInScreenScaleByUserResolution 0 (fScreenPosX fScreenPosY)(fScreenPosX fScreenPosY)

        RETURN_TRUE
        CLEO_RETURN 0 (fScreenPosX fScreenPosY fWidth fHeight)
    ENDIF
    RETURN_FALSE
    CLEO_RETURN 0 (0.0 0.0 0.0 0.0)
}

{
    LVAR_FLOAT fX fY //In
    LVAR_INT iResX iResY
    LVAR_FLOAT fResX fResY
    GetXYSizeInScreenScaleByUserResolution:
    READ_MEMORY 0xC17044 4 FALSE (iResX)
    READ_MEMORY 0xC17048 4 FALSE (iResY)
    fResX =# iResX
    fResY =# iResY
    fResX /= 640.0
    fX /= fResX
    fResY /= 448.0
    fY /= fResY
    CLEO_RETURN 0 fX fY
}

plugin-sdk:
A base de tudo é o uso do CSprite::CalcScreenCoors.
Por exemplo: if (CSprite::CalcScreenCoors({ pos3D.x, pos3D.y, pos3D.z}, &screenPos2D, &sizeX, &sizeY, true, true))